dev-python/pyfakefs: Bump to 5.3.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 46 insertions, 0 deletions

diff --git a/dev-python/pyfakefs/pyfakefs-5.3.2.ebuild b/dev-python/pyfakefs/pyfakefs-5.3.2.ebuild
new file mode 100644
index 000000000000..d5a9d7aac337
--- /dev/null
+++ b/dev-python/pyfakefs/pyfakefs-5.3.2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A fake file system that mocks the Python file system modules"
+HOMEPAGE="
+	https://github.com/pytest-dev/pyfakefs/
+	https://pypi.org/project/pyfakefs/
+"
+SRC_URI="
+	https://github.com/pytest-dev/pyfakefs/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=()
+	local EPYTEST_IGNORE=(
+		# test for regression with opentimelineio package
+		pyfakefs/pytest_tests/segfault_test.py
+	)
+
+	case ${EPYTHON} in
+		python3.12)
+			EPYTEST_DESELECT+=(
+				# happens with pandas + zstandard [cffi backend]
+				# https://github.com/pytest-dev/pyfakefs/issues/910
+				pyfakefs/tests/patched_packages_test.py::TestPatchedPackages::test_read_{csv,table}
+			)
+			;;
+	esac
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p pyfakefs.pytest_plugin
+}