dev-ruby/httparty/httparty-0.5.2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ruby/httparty/httparty-0.5.2.ebuild,v 1.2 2010/03/03 11:15:48 phajdan.jr Exp $

EAPI=2

# ruby19 → testsuite fails (might be crack's bug)
# jruby → testsuite fails (seems like a testuite bug)
USE_RUBY="ruby18"

# We have a custom test function, but don't null this out so that the
# deps are still added
RUBY_FAKEGEM_TASK_TEST="none"

RUBY_FAKEGEM_DOCDIR="rdoc"
RUBY_FAKEGEM_EXTRADOC="README.rdoc History"

inherit ruby-fakegem

DESCRIPTION="Makes http fun! Also, makes consuming restful web services dead easy."
HOMEPAGE="http://httparty.rubyforge.org/"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

# Code should most likely be patched, but for now…
ruby_add_rdepend '~dev-ruby/crack-0.1.6'

ruby_add_bdepend 'dev-ruby/rspec dev-ruby/fakeweb'

USE_RUBY=ruby18 \
	ruby_add_bdepend 'ruby_targets_ruby18 test' 'dev-util/cucumber dev-ruby/activesupport:2.3'

all_ruby_prepare() {
	# as often, Rakefile depends on Jeweler's presence
	sed -i \
		-e '/check_dependencies/s:^:#:' \
		Rakefile || die
}

each_ruby_test() {
	case ${RUBY} in
		*ruby18)
			# Cucumber-based tests only work on Ruby 1.8, as of today, so we only call them
			${RUBY} -S rake spec features || die "cucumber tests failed"
			;;
		*)
			${RUBY} -S rake spec || die "cucumber tests failed"
			;;
	esac
}

all_ruby_install() {
	all_fakegem_install

	docinto examples
	dodoc examples/* || die
}