app-text/bibutils/bibutils-4.2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/bibutils/bibutils-4.2.ebuild,v 1.1 2009/07/26 00:59:36 bicatali Exp $

EAPI=2
inherit toolchain-funcs

MY_P="${PN}_${PV}"
DESCRIPTION="Interconverts between various bibliography formats using a common XML intermediate"
HOMEPAGE="http://www.scripps.edu/~cdputnam/software/bibutils"
SRC_URI="http://www.scripps.edu/~cdputnam/software/bibutils/${MY_P}_src.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""

S="${WORKDIR}/${MY_P}"

src_prepare() {
	# The custom configure script sucks, so we'll just do its
	# job ourselves
	rm -f Makefile configure || die "Failed to purge old Makefile"
	sed \
		-e "s:REPLACE_CC:CC=\"$(tc-getCC) ${CFLAGS}\":g" \
		-e "s:REPLACE_RANLIB:RANLIB=\"$(tc-getRANLIB)\":g" \
		-e "s:REPLACE_INSTALLDIR:\"${D}/usr/bin\":g" \
		-e 's:REPLACE_POSTFIX::g' \
		-e 's:make:$(MAKE):g' \
		Makefile_start > Makefile \
		|| die "Failed to set upt Makefile"
}

src_install() {
	dodir /usr/bin
	emake install || die "emake install failed"
	dodoc ChangeLog
}