From 05324ddd9f1bc7a899f72a4d027c04c30e032b8d Mon Sep 17 00:00:00 2001
From: Tristan Heaven <nyhm@gentoo.org>
Date: Tue, 26 Apr 2011 21:08:03 +0000
Subject: Enable Null Renderer module for games-arcade/smc; Remove doxygen from
 RDEPEND

(Portage version: 2.2.0_alpha30/cvs/Linux x86_64)
---
 dev-games/cegui/ChangeLog             |   7 ++-
 dev-games/cegui/cegui-0.7.5-r1.ebuild | 102 ++++++++++++++++++++++++++++++++++
 2 files changed, 108 insertions(+), 1 deletion(-)
 create mode 100644 dev-games/cegui/cegui-0.7.5-r1.ebuild

(limited to 'dev-games/cegui')

diff --git a/dev-games/cegui/ChangeLog b/dev-games/cegui/ChangeLog
index c013e07c0240..17a0bef6bb9c 100644
--- a/dev-games/cegui/ChangeLog
+++ b/dev-games/cegui/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-games/cegui
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-games/cegui/ChangeLog,v 1.33 2011/04/05 21:23:33 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-games/cegui/ChangeLog,v 1.34 2011/04/26 21:08:03 nyhm Exp $
+
+*cegui-0.7.5-r1 (26 Apr 2011)
+
+  26 Apr 2011; Tristan Heaven <nyhm@gentoo.org> +cegui-0.7.5-r1.ebuild:
+  Enable Null Renderer module for games-arcade/smc; Remove doxygen from RDEPEND
 
   05 Apr 2011; Michael Sterrett <mr_bones_@gentoo.org> cegui-0.7.5.ebuild:
   EAPI=4 for REQUIRED_USE to take care of xml/tinyxml use dep (bug #362223)
diff --git a/dev-games/cegui/cegui-0.7.5-r1.ebuild b/dev-games/cegui/cegui-0.7.5-r1.ebuild
new file mode 100644
index 000000000000..ee0d3f42be6a
--- /dev/null
+++ b/dev-games/cegui/cegui-0.7.5-r1.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-games/cegui/cegui-0.7.5-r1.ebuild,v 1.1 2011/04/26 21:08:03 nyhm Exp $
+
+EAPI=4
+inherit eutils
+
+MY_P=CEGUI-${PV}
+MY_D=CEGUI-DOCS-${PV}
+DESCRIPTION="Crazy Eddie's GUI System"
+HOMEPAGE="http://www.cegui.org.uk/"
+SRC_URI="mirror://sourceforge/crayzedsgui/${MY_P}.tar.gz
+	doc? ( mirror://sourceforge/crayzedsgui/${MY_D}.tar.gz )"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 -ppc ~x86"
+IUSE="bidi debug devil doc examples expat gtk irrlicht lua ogre opengl pcre static-libs tinyxml truetype xerces-c xml zip"
+REQUIRED_USE="|| ( xml tinyxml )" # bug 362223
+
+RDEPEND="bidi? ( dev-libs/fribidi )
+	devil? ( media-libs/devil )
+	expat? ( dev-libs/expat )
+	truetype? ( media-libs/freetype:2 )
+	irrlicht? ( dev-games/irrlicht )
+	lua? (
+		dev-lang/lua
+		dev-lua/toluapp
+	)
+	ogre? ( dev-games/ogre )
+	opengl? (
+		virtual/opengl
+		virtual/glu
+		media-libs/freeglut
+		media-libs/glew
+	)
+	pcre? ( dev-libs/libpcre )
+	tinyxml? ( dev-libs/tinyxml )
+	xerces-c? ( dev-libs/xerces-c )
+	xml? ( dev-libs/libxml2 )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-tinyxml.patch
+
+	if use examples ; then
+		cp -r Samples Samples.clean
+		rm -f $(find Samples.clean -name 'Makefile*')
+	fi
+}
+
+src_configure() {
+	econf \
+		$(use_enable bidi bidirectional-text) \
+		$(use_enable debug) \
+		$(use_enable devil) \
+		$(use_enable examples samples) \
+		$(use_enable expat) \
+		$(use_enable truetype freetype) \
+		$(use_enable irrlicht irrlicht-renderer) \
+		$(use_enable lua lua-module) \
+		$(use_enable lua toluacegui) \
+		--enable-external-toluapp \
+		$(use_enable ogre ogre-renderer) \
+		$(use_enable opengl opengl-renderer) \
+		--enable-external-glew \
+		$(use_enable pcre) \
+		$(use_enable tinyxml) \
+		--enable-external-tinyxml \
+		$(use_enable xerces-c) \
+		$(use_enable xml libxml) \
+		$(use_enable zip minizip-resource-provider) \
+		--enable-null-renderer \
+		--enable-tga \
+		--disable-corona \
+		--disable-dependency-tracking \
+		--disable-samples \
+		--disable-silly \
+		$(use_with gtk gtk2) \
+		$(use_enable static-libs static) \
+		--enable-shared
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+
+	# remove .la files
+	use static-libs || rm -f "${D}"/usr/*/*.la
+
+	if use doc ; then
+		emake html || die
+		dohtml -r doc/doxygen/html/* || die
+	fi
+	if use examples ; then
+		insinto /usr/share/doc/${PF}/Samples
+		doins -r Samples.clean/* || die
+	fi
+}
-- 
cgit v1.2.3-65-gdbad