From 1fdbff76bb8e7979f849503dc6df805c97646f4d Mon Sep 17 00:00:00 2001
From: Brian Evans <grknight@gentoo.org>
Date: Tue, 24 Mar 2015 18:32:11 +0000
Subject: Version bump; Adjusted for new HOMEPAGE and SRC_URI

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key D1F781EFF9F4A3B6)
---
 sys-cluster/galera/ChangeLog             | 10 +++-
 sys-cluster/galera/galera-25.3.10.ebuild | 88 ++++++++++++++++++++++++++++++++
 sys-cluster/galera/galera-25.3.5.ebuild  |  6 +--
 3 files changed, 99 insertions(+), 5 deletions(-)
 create mode 100644 sys-cluster/galera/galera-25.3.10.ebuild

diff --git a/sys-cluster/galera/ChangeLog b/sys-cluster/galera/ChangeLog
index 09b0efc72dfc..fdbd108ea9be 100644
--- a/sys-cluster/galera/ChangeLog
+++ b/sys-cluster/galera/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sys-cluster/galera
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/galera/ChangeLog,v 1.3 2014/10/31 22:06:10 grknight Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/galera/ChangeLog,v 1.4 2015/03/24 18:32:11 grknight Exp $
+
+*galera-25.3.10 (24 Mar 2015)
+
+  24 Mar 2015; Brian Evans <grknight@gentoo.org> +galera-25.3.10.ebuild,
+  galera-25.3.5.ebuild:
+  Version bump; Adjusted for new HOMEPAGE and SRC_URI
 
   31 Oct 2014; Brian Evans <grknight@gentoo.org> files/garb.sh,
   galera-25.3.5.ebuild:
diff --git a/sys-cluster/galera/galera-25.3.10.ebuild b/sys-cluster/galera/galera-25.3.10.ebuild
new file mode 100644
index 000000000000..6587abecb3d0
--- /dev/null
+++ b/sys-cluster/galera/galera-25.3.10.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/galera/galera-25.3.10.ebuild,v 1.1 2015/03/24 18:32:11 grknight Exp $
+
+EAPI=5
+
+inherit scons-utils multilib toolchain-funcs eutils user
+
+MY_PV="release_${PV}"
+DESCRIPTION="Synchronous multi-master replication engine that provides its service through wsrep API"
+HOMEPAGE="http://www.galeracluster.com/"
+SRC_URI="https://github.com/codership/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="GPL-2 BSD"
+
+SLOT="0"
+
+KEYWORDS="~amd64 ~x86"
+IUSE="garbd ssl test"
+
+CDEPEND="
+	 ssl? ( dev-libs/openssl:0= )
+	>=dev-libs/boost-1.41:0=
+	"
+DEPEND="${DEPEND}
+	${CDEPEND}
+	dev-libs/check
+	>=sys-devel/gcc-4.4
+	>=dev-cpp/asio-1.4.8[ssl?]
+	"
+#Run time only
+RDEPEND="${CDEPEND}
+	garbd? ( || (
+		net-analyzer/netcat
+		net-analyzer/netcat6
+		net-analyzer/gnu-netcat
+		net-analyzer/openbsd-netcat
+	) )"
+
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+pkg_preinst() {
+	if use garbd ; then
+		enewgroup garbd
+		enewuser garbd -1 -1 -1 garbd
+	fi
+}
+
+src_prepare() {
+	# Remove bundled dev-cpp/asio
+	rm -r "${S}/asio" || die
+
+	# Respect {C,LD}FLAGS.
+	epatch "${FILESDIR}/respect-flags.patch"
+
+	#Remove optional garbd daemon
+	if ! use garbd ; then
+		rm -r "${S}/garb" || die
+	fi
+
+	epatch_user
+}
+
+src_configure() {
+	tc-export CC CXX
+	# strict_build_flags=0 disables -Werror, -pedantic, -Weffc++,
+	# and -Wold-style-cast
+	myesconsargs=(
+		$(use_scons ssl ssl 1 0)
+		$(use_scons test tests 1 0)
+		strict_build_flags=0
+	)
+}
+
+src_compile() {
+	escons --warn=no-missing-sconscript
+}
+
+src_install() {
+	dodoc scripts/packages/README scripts/packages/README-MySQL
+	if use garbd ; then
+		dobin garb/garbd
+		newconfd "${FILESDIR}/garb.cnf" garbd
+		newinitd "${FILESDIR}/garb.sh" garbd
+		doman man/garbd.8
+	fi
+	exeinto /usr/$(get_libdir)/${PN}
+	doexe libgalera_smm.so
+}
diff --git a/sys-cluster/galera/galera-25.3.5.ebuild b/sys-cluster/galera/galera-25.3.5.ebuild
index d5d7810c1c43..461993f645e6 100644
--- a/sys-cluster/galera/galera-25.3.5.ebuild
+++ b/sys-cluster/galera/galera-25.3.5.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2014 Gentoo Foundation
+# Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/galera/galera-25.3.5.ebuild,v 1.3 2014/10/31 22:06:10 grknight Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/galera/galera-25.3.5.ebuild,v 1.4 2015/03/24 18:32:11 grknight Exp $
 
 EAPI=5
 
@@ -18,7 +18,7 @@ KEYWORDS="~amd64 ~x86"
 IUSE="garbd ssl test"
 
 CDEPEND="
-	 ssl? ( dev-libs/openssl )
+	 ssl? ( dev-libs/openssl:0= )
 	>=dev-libs/boost-1.41
 	"
 DEPEND="${DEPEND}
-- 
cgit v1.2.3-65-gdbad