1 files changed, 68 insertions, 0 deletions
diff --git a/app-i18n/ibus-pinyin/ibus-pinyin-1.3.99.20110520.ebuild b/app-i18n/ibus-pinyin/ibus-pinyin-1.3.99.20110520.ebuild
new file mode 100644
index 000000000000..5323d1d07a0b
--- /dev/null
+++ b/app-i18n/ibus-pinyin/ibus-pinyin-1.3.99.20110520.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus-pinyin/ibus-pinyin-1.3.99.20110520.ebuild,v 1.1 2011/06/06 16:25:13 matsuu Exp $
+
+EAPI="3"
+PYTHON_DEPEND="2:2.5"
+PYTHON_USE_WITH="sqlite"
+inherit python eutils
+
+PYDB_TAR="pinyin-database-1.2.99.tar.bz2"
+DESCRIPTION="Chinese PinYin IMEngine for IBus Framework"
+HOMEPAGE="http://code.google.com/p/ibus/"
+SRC_URI="http://ibus.googlecode.com/files/${P}.tar.gz
+	http://ibus.googlecode.com/files/${PYDB_TAR}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="boost lua nls opencc"
+
+RDEPEND=">=app-i18n/ibus-1.3.99
+	sys-apps/util-linux
+	boost? (
+		>=dev-libs/boost-1.39
+		!=dev-libs/boost-1.46.1
+	)
+	lua? ( >=dev-lang/lua-5.1 )
+	nls? ( virtual/libintl )
+	opencc? ( app-i18n/opencc )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	nls? ( >=sys-devel/gettext-0.16.1 )"
+
+pkg_setup() {
+	python_set_active_version 2
+	python_pkg_setup
+}
+
+src_prepare() {
+	cp "${DISTDIR}/${PYDB_TAR}" "${S}"/data/db/open-phrase/ || die
+	mv py-compile py-compile.orig || die
+	ln -s "$(type -P true)" py-compile || die
+}
+
+src_configure() {
+	econf \
+		$(use_enable boost) \
+		$(use_enable lua lua-extension) \
+		$(use_enable nls) \
+		$(use_enable opencc) \
+		--enable-db-open-phrase
+		#--disable-db-android \
+		#--disable-english-input-mode \
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+
+	dodoc AUTHORS ChangeLog NEWS README || die
+}
+
+pkg_postinst() {
+	python_mod_optimize /usr/share/${PN}
+}
+
+pkg_postrm() {
+	python_mod_cleanup /usr/share/${PN}
+}