Version Bump; add py3 and pypy support

(Portage version: 2.2.17/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

2 files changed, 58 insertions, 2 deletions

diff --git a/sci-biology/biopython/ChangeLog b/sci-biology/biopython/ChangeLog
index 8b94d92d48fe..c7671622e36e 100644
--- a/sci-biology/biopython/ChangeLog
+++ b/sci-biology/biopython/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sci-biology/biopython
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-biology/biopython/ChangeLog,v 1.76 2014/06/03 06:54:27 jlec Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sci-biology/biopython/ChangeLog,v 1.77 2015/03/03 16:01:46 jlec Exp $
+
+*biopython-1.65 (03 Mar 2015)
+
+  03 Mar 2015; Justin Lecher <jlec@gentoo.org> +biopython-1.65.ebuild:
+  Version Bump; add py3 and pypy support
 
 *biopython-1.64 (03 Jun 2014)
 
diff --git a/sci-biology/biopython/biopython-1.65.ebuild b/sci-biology/biopython/biopython-1.65.ebuild
new file mode 100644
index 000000000000..0beaaac49e22
--- /dev/null
+++ b/sci-biology/biopython/biopython-1.65.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-biology/biopython/biopython-1.65.ebuild,v 1.1 2015/03/03 16:01:46 jlec Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4} pypy )
+
+inherit distutils-r1 eutils
+
+DESCRIPTION="Python modules for computational molecular biology"
+HOMEPAGE="http://www.biopython.org/ http://pypi.python.org/pypi/biopython/"
+SRC_URI="http://www.biopython.org/DIST/${P}.tar.gz"
+
+LICENSE="HPND"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
+IUSE=""
+
+RDEPEND="
+	dev-python/matplotlib[$(python_gen_usedep 'python*')]
+	dev-python/networkx[$(python_gen_usedep 'python*')]
+	dev-python/numpy[$(python_gen_usedep 'python*')]
+	dev-python/rdflib[$(python_gen_usedep 'python*')]
+	dev-python/pygraphviz[$(python_gen_usedep 'python2*')]
+	dev-python/reportlab[$(python_gen_usedep 'python*')]
+	media-gfx/pydot[$(python_gen_usedep 'python2*')]
+	"
+DEPEND="${RDEPEND}
+	sys-devel/flex"
+
+DOCS=( CONTRIB DEPRECATED NEWS README Doc/. )
+
+python_test() {
+	[[ ${EPYTHON} == pypy ]] && return
+	cd Tests || die
+	${PYTHON} run_tests.py || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	dodir /usr/share/${PN}
+	cp -r --preserve=mode Scripts Tests "${ED}"/usr/share/${PN} || die
+}
+
+pkg_postinst() {
+	elog "For database support you need to install:"
+	optfeature "MySQL" dev-python/mysql-python
+	optfeature "PostGreSQL" dev-python/psycopg
+}