Version bump to 0.12.3, fix qt-gui version for <0.12.3, wrt to bug #435090

(Portage version: 2.1.11.9/cvs/Linux x86_64)

3 files changed, 107 insertions, 2 deletions

diff --git a/net-im/kadu/ChangeLog b/net-im/kadu/ChangeLog
index 507450593ac2..274e2e5dae7d 100644
--- a/net-im/kadu/ChangeLog
+++ b/net-im/kadu/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-im/kadu
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/kadu/ChangeLog,v 1.142 2012/09/15 10:31:51 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/kadu/ChangeLog,v 1.143 2012/09/15 10:51:55 ago Exp $
+
+*kadu-0.12.3 (15 Sep 2012)
+
+  15 Sep 2012; Agostino Sarubbo <ago@gentoo.org> +kadu-0.12.3.ebuild,
+  kadu-0.12.0.ebuild:
+  Version bump to 0.12.3, fix qt-gui version for <0.12.3, wrt to bug #435090
 
   15 Sep 2012; Tomáš Chvátal <scarabeus@gentoo.org> kadu-0.12.0.ebuild:
   Stable on ppc wrt bug#428648.
diff --git a/net-im/kadu/kadu-0.12.0.ebuild b/net-im/kadu/kadu-0.12.0.ebuild
index 24d4c46bfc63..9a5b7d878aae 100644
--- a/net-im/kadu/kadu-0.12.0.ebuild
+++ b/net-im/kadu/kadu-0.12.0.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/kadu/kadu-0.12.0.ebuild,v 1.4 2012/09/15 10:31:51 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/kadu/kadu-0.12.0.ebuild,v 1.5 2012/09/15 10:51:55 ago Exp $
 
 EAPI="4"
 
@@ -29,6 +29,7 @@ COMMON_DEPEND="
 	x11-libs/libXScrnSaver
 	>=x11-libs/qt-dbus-4.7.0:4
 	>=x11-libs/qt-gui-4.7.0:4
+	<x11-libs/qt-gui-4.8.3:4
 	>=x11-libs/qt-script-4.7.0:4
 	>=x11-libs/qt-sql-4.7.0:4[sqlite]
 	>=x11-libs/qt-webkit-4.7.0:4
diff --git a/net-im/kadu/kadu-0.12.3.ebuild b/net-im/kadu/kadu-0.12.3.ebuild
new file mode 100644
index 000000000000..ce3e28539469
--- /dev/null
+++ b/net-im/kadu/kadu-0.12.3.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-im/kadu/kadu-0.12.3.ebuild,v 1.1 2012/09/15 10:51:55 ago Exp $
+
+EAPI="4"
+
+inherit base cmake-utils flag-o-matic
+
+MY_P="${P/_/-}"
+
+DESCRIPTION="An open source Gadu-Gadu and Jabber/XMPP protocol Instant Messenger client."
+HOMEPAGE="http://www.kadu.net"
+SRC_URI="http://download.kadu.im/stable/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~ppc ~x86"
+SLOT="0"
+IUSE="ayatana +gadu mpd phonon sdk speech spell xmpp"
+REQUIRED_USE="
+	|| (
+		gadu
+		xmpp
+	)
+"
+COMMON_DEPEND="
+	>=app-crypt/qca-2.0.0-r2
+	x11-libs/libX11
+	x11-libs/libXfixes
+	x11-libs/libXScrnSaver
+	>=x11-libs/qt-dbus-4.7.0:4
+	>=x11-libs/qt-gui-4.7.0:4
+	>=x11-libs/qt-script-4.7.0:4
+	>=x11-libs/qt-sql-4.7.0:4[sqlite]
+	>=x11-libs/qt-webkit-4.7.0:4
+	ayatana? ( dev-libs/libindicate-qt )
+	gadu? (
+		>=net-libs/libgadu-1.11.1[threads]
+		>=x11-libs/qt-xmlpatterns-4.7.0:4
+	)
+	mpd? ( media-libs/libmpdclient )
+	phonon? (
+		|| (
+			media-libs/phonon
+			>=x11-libs/qt-phonon-4.7.0:4
+		)
+	)
+	spell? ( app-text/enchant )
+	xmpp? (
+		net-dns/libidn
+		sys-libs/zlib
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	x11-proto/fixesproto
+	x11-proto/scrnsaverproto
+	x11-proto/xproto
+"
+RDEPEND="${COMMON_DEPEND}
+	app-crypt/qca-ossl:2
+	>=x11-libs/qt-svg-4.7.0:4
+	speech? ( app-accessibility/powiedz )
+"
+
+PLUGINS='amarok1_mediaplayer antistring auto_hide autoaway autoresponder autostatus cenzor chat_notify config_wizard desktop_docking docking encryption_ng encryption_ng_simlite exec_notify ext_sound falf_mediaplayer filedesc firewall freedesktop_notify hints history idle imagelink last_seen mediaplayer mprisplayer_mediaplayer pcspeaker qt4_docking qt4_docking_notify screenshot simpleview single_window sms sound sql_history tabs word_fix'
+
+src_configure() {
+	# Filter out dangerous flags
+	filter-flags -fno-rtti
+	strip-unsupported-flags
+
+	# Ensure -DQT_NO_DEBUG is added
+	append-cppflags -DQT_NO_DEBUG
+
+	# Plugin selection
+	if use gadu; then
+		PLUGINS+=' gadu_protocol history_migration profiles_import'
+	fi
+
+	use mpd && PLUGINS+=' mpd_mediaplayer'
+	use xmpp && PLUGINS+=' jabber_protocol'
+	use phonon && PLUGINS+=' phonon_sound'
+	use speech && PLUGINS+=' speech'
+	use spell && PLUGINS+=' spellchecker'
+
+	# Configure package
+	local mycmakeargs=(
+		-DBUILD_DESCRIPTION='Gentoo Linux'
+		-DCOMPILE_PLUGINS="${PLUGINS}"
+		-DNETWORK_IMPLEMENTATION="Qt"
+		-DSIG_HANDLING_ENABLED=TRUE
+		$(cmake-utils_use sdk INSTALL_SDK)
+		$(cmake-utils_use_with ayatana INDICATE_QT)
+		$(cmake-utils_use_with spell ENCHANT)
+	)
+	unset PLUGINS
+
+	cmake-utils_src_configure
+}