Add latest release (bug 280085)

(Portage version: 2.2_rc42/cvs/Linux x86_64)

2 files changed, 67 insertions, 1 deletions

diff --git a/media-sound/rubyripper/ChangeLog b/media-sound/rubyripper/ChangeLog
index 066f8f803266..6246c38b4df4 100644
--- a/media-sound/rubyripper/ChangeLog
+++ b/media-sound/rubyripper/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/rubyripper
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/rubyripper/ChangeLog,v 1.27 2009/05/14 19:33:56 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/rubyripper/ChangeLog,v 1.28 2009/09/30 22:23:25 yngwin Exp $
+
+*rubyripper-0.5.7 (30 Sep 2009)
+
+  30 Sep 2009; Ben de Groot <yngwin@gentoo.org> +rubyripper-0.5.7.ebuild:
+  Add latest release (bug 280085)
 
   14 May 2009; Markus Meier <maekke@gentoo.org> rubyripper-0.5.5-r1.ebuild:
   amd64/x86 stable, bug #269294
diff --git a/media-sound/rubyripper/rubyripper-0.5.7.ebuild b/media-sound/rubyripper/rubyripper-0.5.7.ebuild
new file mode 100644
index 000000000000..ac5d16772aec
--- /dev/null
+++ b/media-sound/rubyripper/rubyripper-0.5.7.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/rubyripper/rubyripper-0.5.7.ebuild,v 1.1 2009/09/30 22:23:25 yngwin Exp $
+
+EAPI=2
+inherit ruby virtualx
+
+DESCRIPTION="A secure audio ripper for Linux"
+HOMEPAGE="http://code.google.com/p/rubyripper"
+SRC_URI="http://${PN}.googlecode.com/files/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~sparc ~x86"
+IUSE="cli flac +gtk +mp3 normalize +vorbis wav X"
+
+ILINGUAS="de es fr hu nl ru"
+
+for lingua in $ILINGUAS; do
+	IUSE="${IUSE} linguas_${lingua}"
+done
+
+RDEPEND="gtk? ( dev-ruby/ruby-gtk2
+	>=dev-ruby/rcairo-1.8.0-r1[svg] )
+	virtual/eject
+	media-sound/cd-discid
+	media-sound/cdparanoia
+	flac? ( media-libs/flac )
+	mp3? ( media-sound/lame )
+	vorbis? ( media-sound/vorbis-tools )
+	normalize? ( media-sound/normalize
+		mp3? ( media-sound/mp3gain )
+		vorbis? ( media-sound/vorbisgain )
+		wav? ( media-sound/wavegain ) )"
+DEPEND="${RDEPEND}
+	dev-ruby/ruby-gettext"
+
+src_prepare() {
+	# fix for bug 203737
+	epatch "${FILESDIR}"/${PN}-0.5.2-require-rubygems.patch
+}
+
+src_configure() {
+	local myconf="--prefix=/usr"
+	local enable_linguas=""
+
+	for lingua in $ILINGUAS; do
+		use linguas_$lingua && enable_linguas="${enable_linguas},${lingua}"
+	done
+
+	[[ -n ${enable_linguas} ]] && myconf="${myconf} --enable-lang=${enable_linguas#,}"
+
+	use gtk && myconf="${myconf} --enable-gtk2"
+	use cli && myconf="${myconf} --enable-cli"
+
+	Xeconf ${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+}