Add new digikam for testing.

(Portage version: 2.2_rc49/cvs/Linux x86_64)

3 files changed, 83 insertions, 1 deletions

diff --git a/media-gfx/digikam/ChangeLog b/media-gfx/digikam/ChangeLog
index bba82a92c531..df8205fcaaac 100644
--- a/media-gfx/digikam/ChangeLog
+++ b/media-gfx/digikam/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-gfx/digikam
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/digikam/ChangeLog,v 1.144 2009/10/24 13:10:20 nixnut Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/digikam/ChangeLog,v 1.145 2009/11/15 19:20:44 scarabeus Exp $
+
+*digikam-1.0.0_beta6 (15 Nov 2009)
+
+  15 Nov 2009; Tomáš Chvátal <scarabeus@gentoo.org>
+  +digikam-1.0.0_beta6.ebuild, metadata.xml:
+  Add new digikam for testing.
 
   24 Oct 2009; nixnut <nixnut@gentoo.org> digikam-0.9.5-r1.ebuild:
   ppc stable #287980
diff --git a/media-gfx/digikam/digikam-1.0.0_beta6.ebuild b/media-gfx/digikam/digikam-1.0.0_beta6.ebuild
new file mode 100644
index 000000000000..bbeb17de4635
--- /dev/null
+++ b/media-gfx/digikam/digikam-1.0.0_beta6.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/digikam/digikam-1.0.0_beta6.ebuild,v 1.1 2009/11/15 19:20:44 scarabeus Exp $
+
+EAPI="2"
+
+KDE_LINGUAS="ar be bg ca cs da de el es et eu fa fi fr ga gl he hi is it ja km
+ko lt lv lb nds ne nl nn pa pl pt pt_BR ro ru se sk sl sv th tr uk vi zh_CN zh_TW"
+KMNAME="extragear/graphics"
+inherit kde4-base
+
+MY_P="${PN}-${PV/_/-}"
+
+DESCRIPTION="A digital photo management application for KDE."
+HOMEPAGE="http://www.digikam.org/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2
+	http://dev.gentooexperimental.org/~scarabeus/digikam-1.0.0-beta6.patch.bz2
+"
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~x86"
+SLOT="4"
+IUSE="addressbook debug geolocation gphoto2 lensfun semantic-desktop +thumbnails"
+
+RDEPEND="
+	>=kde-base/kdelibs-${KDE_MINIMAL}[semantic-desktop?]
+	>=kde-base/libkdcraw-${KDE_MINIMAL}
+	>=kde-base/libkexiv2-${KDE_MINIMAL}
+	>=kde-base/libkipi-${KDE_MINIMAL}
+	>=kde-base/solid-${KDE_MINIMAL}
+	media-libs/jasper
+	media-libs/jpeg
+	media-libs/lcms
+	media-libs/liblqr
+	media-libs/libpng
+	media-libs/tiff
+	x11-libs/qt-gui[qt3support]
+	x11-libs/qt-sql[sqlite]
+	addressbook? ( >=kde-base/kdepimlibs-${KDE_MINIMAL} )
+	geolocation? ( >=kde-base/marble-${KDE_MINIMAL} )
+	gphoto2? ( >=media-libs/libgphoto2-2.4.1-r1 )
+	lensfun? ( media-libs/lensfun )
+"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	epatch "${WORKDIR}"/${MY_P}.patch
+
+	kde4-base_src_prepare
+}
+
+src_configure() {
+	local backend
+
+	use semantic-desktop && backend="Nepomuk" || backend="None"
+	# LQR = only allows to choose between bundled/external
+	mycmakeargs="${mycmakeargs}
+		-DWITH_LQR=ON
+		-DENABLE_THEMEDESIGNER=OFF
+		-DGWENVIEW_SEMANTICINFO_BACKEND=${backend}
+		$(cmake-utils_use_enable gphoto2 GPHOTO2)
+		$(cmake-utils_use_with gphoto2)
+		$(cmake-utils_use_enable thumbnails THUMBS_DB)
+		$(cmake-utils_use_with addressbook KdepimLibs)
+		$(cmake-utils_use_with geolocation MarbleWidget)
+		$(cmake-utils_use_with lensfun LensFun)
+		$(cmake-utils_use_with semantic-desktop Soprano)"
+
+	kde4-base_src_configure
+}
diff --git a/media-gfx/digikam/metadata.xml b/media-gfx/digikam/metadata.xml
index 35d5a241bd35..83cf79da2c4b 100644
--- a/media-gfx/digikam/metadata.xml
+++ b/media-gfx/digikam/metadata.xml
@@ -6,5 +6,7 @@
 	<flag name="nfs">Create sqlite db within ~/.kde, instead in the albums base directory.</flag>
 	<flag name="addressbook">Add support for kdepim</flag>
 	<flag name="geolocation">Add support for marble</flag>
+	<flag name="lensfun">Enable support for lens-correnction library</flag>
+	<flag name="thumbnails">Allow thumbnail previews for images/photos</flag>
 </use>
 </pkgmetadata>