Version bump.

(Portage version: 2.2.0_alpha89/cvs/Linux x86_64)

2 files changed, 84 insertions, 1 deletions

diff --git a/games-strategy/naev/ChangeLog b/games-strategy/naev/ChangeLog
index e6adfa5a0aa5..e1cd2df37be8 100644
--- a/games-strategy/naev/ChangeLog
+++ b/games-strategy/naev/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for games-strategy/naev
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-strategy/naev/ChangeLog,v 1.8 2012/03/02 02:00:40 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/naev/ChangeLog,v 1.9 2012/03/02 02:12:46 ssuominen Exp $
+
+*naev-0.5.1 (02 Mar 2012)
+
+  02 Mar 2012; Samuli Suominen <ssuominen@gentoo.org> +naev-0.5.1.ebuild:
+  Version bump.
 
   02 Mar 2012; Samuli Suominen <ssuominen@gentoo.org> -naev-0.4.2.ebuild:
   old
diff --git a/games-strategy/naev/naev-0.5.1.ebuild b/games-strategy/naev/naev-0.5.1.ebuild
new file mode 100644
index 000000000000..232062142aa5
--- /dev/null
+++ b/games-strategy/naev/naev-0.5.1.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/naev/naev-0.5.1.ebuild,v 1.1 2012/03/02 02:12:46 ssuominen Exp $
+
+EAPI=2
+inherit gnome2-utils games
+
+DESCRIPTION="A 2D space trading and combat game, in a similar vein to Escape Velocity"
+HOMEPAGE="http://code.google.com/p/naev/"
+SRC_URI="mirror://sourceforge/naev/${P}.tar.bz2
+	mirror://sourceforge/naev/ndata-${PV}"
+
+LICENSE="GPL-2 GPL-3 public-domain CCPL-Attribution-3.0 CCPL-Attribution-ShareAlike-3.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug +mixer +openal"
+
+RDEPEND="media-libs/libsdl[X,audio,video]
+	dev-libs/libxml2
+	>=media-libs/freetype-2
+	>=media-libs/libvorbis-1.2.1
+	>=media-libs/libpng-1.2:0
+	media-libs/sdl-image[png]
+	virtual/glu
+	virtual/opengl
+	mixer? ( media-libs/sdl-mixer )
+	openal? ( media-libs/openal )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+src_unpack() {
+	unpack ${P}.tar.bz2
+}
+
+src_configure() {
+	egamesconf \
+		--docdir=/usr/share/doc/${PF} \
+		--disable-dependency-tracking \
+		$(use_enable debug) \
+		$(use_with openal) \
+		$(use_with mixer sdlmixer)
+}
+
+src_install() {
+	emake \
+		DESTDIR="${D}" \
+		appicondir=/usr/share/pixmaps \
+		Graphicsdir=/usr/share/applications \
+		install || die
+
+	insinto "${GAMES_DATADIR}"/${PN}
+	newins "${DISTDIR}"/ndata-${PV} ndata || die
+
+	local res
+	for res in 16 32 64 128; do
+		insinto /usr/share/icons/hicolor/${res}x${res}/apps
+		newins extras/logos/logo${res}.png naev.png || die
+	done
+
+	rm -f "${D}"/usr/share/doc/${PF}/LICENSE
+	prepalldocs
+
+	prepgamesdirs
+}
+
+pkg_preinst() {
+	games_pkg_preinst
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	games_pkg_postinst
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}