Version bump by Fortunato Ventre, bug #190991

(Portage version: 2.1.3.7)

3 files changed, 118 insertions, 1 deletions

diff --git a/games-fps/warsow/ChangeLog b/games-fps/warsow/ChangeLog
index b061c544e3a8..22bc45bba3ed 100644
--- a/games-fps/warsow/ChangeLog
+++ b/games-fps/warsow/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for games-fps/warsow
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-fps/warsow/ChangeLog,v 1.7 2007/07/05 15:57:37 nyhm Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-fps/warsow/ChangeLog,v 1.8 2007/09/05 23:01:54 nyhm Exp $
+
+*warsow-0.3.2 (05 Sep 2007)
+
+  05 Sep 2007; Tristan Heaven <nyhm@gentoo.org> +warsow-0.3.2.ebuild:
+  Version bump by Fortunato Ventre, bug #190991
 
 *warsow-0.3.1-r1 (05 Jul 2007)
 
diff --git a/games-fps/warsow/files/digest-warsow-0.3.2 b/games-fps/warsow/files/digest-warsow-0.3.2
new file mode 100644
index 000000000000..418d17c9c04f
--- /dev/null
+++ b/games-fps/warsow/files/digest-warsow-0.3.2
@@ -0,0 +1,9 @@
+MD5 d5eac4a33b3543dbc40d984b84e657f8 warsow.png 1692
+RMD160 098a1505a74a20eb4bdfeda4cf2c537a9524ce23 warsow.png 1692
+SHA256 086968e72271b248ef32609ed1818ff9f5c355297b1eee3cbee9e41f4e18a954 warsow.png 1692
+MD5 508fa64b6157b3f5ebed09e9e715ec43 warsow_0.32_linux.tar.gz 98620461
+RMD160 45977b8e2dbfa9c6ed1ee2a7345fb8c5a5ecbbee warsow_0.32_linux.tar.gz 98620461
+SHA256 e74fe6b66bbb64c43109526f5a30c5488ca020e6caba588e3e40b96e6a4579c3 warsow_0.32_linux.tar.gz 98620461
+MD5 551b7a0cebd0c02968ce86fb12cd86b7 warsow_0.32_sdk.zip 19271033
+RMD160 a7df07cf92ad8fcc12adeb22346f29df9b3b9e38 warsow_0.32_sdk.zip 19271033
+SHA256 0cfb8456d36fee68ce7a0be399219a9ba5dcf65e254d86da308ab05b42dd3f4a warsow_0.32_sdk.zip 19271033
diff --git a/games-fps/warsow/warsow-0.3.2.ebuild b/games-fps/warsow/warsow-0.3.2.ebuild
new file mode 100644
index 000000000000..fb724c719cda
--- /dev/null
+++ b/games-fps/warsow/warsow-0.3.2.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-fps/warsow/warsow-0.3.2.ebuild,v 1.1 2007/09/05 23:01:54 nyhm Exp $
+
+inherit eutils toolchain-funcs versionator games
+
+MY_P=${PN}_$(delete_version_separator 2)
+DESCRIPTION="Multiplayer FPS based on the QFusion engine (evolved from Quake 2)"
+HOMEPAGE="http://www.warsow.net/"
+SRC_URI="http://www.megami.de/warsow/releases/${MY_P}_linux.tar.gz
+	http://www.megami.de/warsow/releases/${MY_P}_sdk.zip
+	mirror://gentoo/${PN}.png"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug dedicated irc openal opengl"
+
+UIRDEPEND="media-libs/jpeg
+	media-libs/libvorbis
+	media-libs/libsdl
+	net-misc/curl
+	virtual/opengl
+	x11-libs/libXinerama
+	x11-libs/libXxf86dga
+	x11-libs/libXxf86vm
+	openal? ( media-libs/openal )"
+RDEPEND="opengl? ( ${UIRDEPEND} )
+	!opengl? ( !dedicated? ( ${UIRDEPEND} ) )"
+DEPEND="${RDEPEND}
+	app-arch/unzip
+	x11-misc/makedepend"
+
+S=${WORKDIR}/${MY_P}/source
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	rm -f "${WORKDIR}"/${PN}/docs/gnu.txt
+
+	sed -i \
+		-e '/fs_usehomedir =/ s:0:1:' \
+		-e "/fs_basepath =/ s:\.:${GAMES_DATADIR}/${PN}:" \
+		qcommon/files.c \
+		|| die "sed files.c failed"
+
+	epatch "${FILESDIR}"/${P}-build.patch
+}
+
+src_compile() {
+	yesno() { use ${1} && echo YES || echo NO ; }
+
+	if use opengl || ! use dedicated ; then
+		local client="YES"
+	else
+		local client="NO"
+	fi
+
+	emake \
+		BUILD_CLIENT=${client} \
+		BUILD_SERVER=$(yesno dedicated) \
+		BUILD_IRC=$(yesno irc) \
+		BUILD_SND_OPENAL=$(yesno openal) \
+		DEBUG_BUILD=$(yesno debug) \
+		CC="$(tc-getCC)" \
+		LD="$(tc-getCC)" \
+		|| die "emake failed"
+}
+
+src_install() {
+	cd release
+
+	if use opengl || ! use dedicated ; then
+		newgamesbin ${PN}.* ${PN} || die "newgamesbin ${PN} failed"
+		doicon "${DISTDIR}"/${PN}.png
+		make_desktop_entry ${PN} Warsow
+	fi
+
+	if use dedicated ; then
+		newgamesbin wsw_server.* ${PN}-ded || die "newgamesbin ${PN}-ded failed"
+	fi
+
+	exeinto "$(games_get_libdir)"/${PN}
+	doexe */*.so || die "doexe failed"
+
+	insinto "${GAMES_DATADIR}"/${PN}
+	doins -r "${WORKDIR}"/${PN}/basewsw || die "doins failed"
+
+	local so
+	for so in basewsw/*.so ; do
+		dosym "$(games_get_libdir)"/${PN}/${so##*/} \
+			"${GAMES_DATADIR}"/${PN}/${so} || die "dosym ${so} failed"
+	done
+
+	dodir "${GAMES_DATADIR}"/${PN}/libs
+	for so in libs/*.so ; do
+		dosym "$(games_get_libdir)"/${PN}/${so##*/} \
+			"${GAMES_DATADIR}"/${PN}/${so} || die "dosym ${so} failed"
+	done
+
+	dodoc "${WORKDIR}"{/${PN},}/docs/*
+	prepgamesdirs
+}