Initial import, ebuild by me.

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

1 files changed, 42 insertions, 0 deletions

diff --git a/dev-python/backports-ssl-match-hostname/backports-ssl-match-hostname-3.4.0.2.ebuild b/dev-python/backports-ssl-match-hostname/backports-ssl-match-hostname-3.4.0.2.ebuild
new file mode 100644
index 000000000000..0c7d30ac6228
--- /dev/null
+++ b/dev-python/backports-ssl-match-hostname/backports-ssl-match-hostname-3.4.0.2.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/backports-ssl-match-hostname/backports-ssl-match-hostname-3.4.0.2.ebuild,v 1.1 2014/01/26 13:08:49 radhermit Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit distutils-r1
+
+MY_PN=${PN/-/.}
+MY_PN=${MY_PN//-/_}
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Backport of the ssl.match_hostname function"
+HOMEPAGE="https://pypi.python.org/pypi/backports.ssl_match_hostname/"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="PYTHON"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+RDEPEND="dev-python/backports[${PYTHON_USEDEP}]"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	# prevent unnecessary docs from being installed in site-packages
+	mv src/backports/ssl_match_hostname/{LICENSE,README}.txt "${S}" || die
+}
+
+python_install_all() {
+	local DOCS=( README.txt )
+	distutils-r1_python_install_all
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# main namespace provided by dev-python/backports
+	rm "${ED}$(python_get_sitedir)"/backports/__init__.py* || die
+}