Version bump (bug #467470), add doc and static-libs use flags.

(Portage version: 2.2.0_alpha173/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

2 files changed, 70 insertions, 2 deletions

diff --git a/dev-libs/xmlsec/ChangeLog b/dev-libs/xmlsec/ChangeLog
index be669a19118c..0bb640caea8b 100644
--- a/dev-libs/xmlsec/ChangeLog
+++ b/dev-libs/xmlsec/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/xmlsec
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/xmlsec/ChangeLog,v 1.33 2012/05/04 18:35:51 jdhore Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/xmlsec/ChangeLog,v 1.34 2013/05/02 07:19:09 radhermit Exp $
+
+*xmlsec-1.2.19 (02 May 2013)
+
+  02 May 2013; Tim Harder <radhermit@gentoo.org> +xmlsec-1.2.19.ebuild:
+  Version bump (bug #467470), add doc and static-libs use flags.
 
   04 May 2012; Jeff Horelick <jdhore@gentoo.org> xmlsec-1.2.18.ebuild:
   dev-util/pkgconfig -> virtual/pkgconfig
diff --git a/dev-libs/xmlsec/xmlsec-1.2.19.ebuild b/dev-libs/xmlsec/xmlsec-1.2.19.ebuild
new file mode 100644
index 000000000000..0b9b229b9297
--- /dev/null
+++ b/dev-libs/xmlsec/xmlsec-1.2.19.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/xmlsec/xmlsec-1.2.19.ebuild,v 1.1 2013/05/02 07:19:09 radhermit Exp $
+
+EAPI=5
+
+inherit eutils autotools
+
+DESCRIPTION="Command line tool for signing, verifying, encrypting and decrypting XML"
+HOMEPAGE="http://www.aleksey.com/xmlsec"
+SRC_URI="http://www.aleksey.com/xmlsec/download/${PN}1-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="doc gcrypt gnutls nss +openssl static-libs"
+REQUIRED_USE="|| ( gcrypt gnutls nss openssl )
+	gnutls? ( gcrypt )"
+
+RDEPEND=">=dev-libs/libxml2-2.7.4
+	>=dev-libs/libxslt-1.0.20
+	gcrypt? ( >=dev-libs/libgcrypt-1.4.0 )
+	gnutls? ( >=net-libs/gnutls-2.8.0 )
+	nss? (
+		>=dev-libs/nspr-4.4.1
+		>=dev-libs/nss-3.9
+	)
+	openssl? ( >=dev-libs/openssl-0.9.7 )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${PN}1-${PV}
+
+src_prepare() {
+	# conditionally install extra documentation
+	if ! use doc ; then
+		sed -i '/^SUBDIRS/s/docs//' Makefile.am || die
+		eautoreconf
+	fi
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		$(use_with gcrypt gcrypt "") \
+		$(use_with gnutls gnutls "") \
+		$(use_with nss nspr "") \
+		$(use_with nss nss "") \
+		$(use_enable openssl aes) \
+		$(use_with openssl openssl "") \
+		--enable-pkgconfig \
+		--enable-xkms \
+		--with-html-dir=/usr/share/doc/${PF}/html
+}
+
+src_test() {
+	emake TMPFOLDER="${T}" check
+}
+
+src_install() {
+	default
+	prune_libtool_files
+}