Convert to python-single-r1.

(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

2 files changed, 87 insertions, 2 deletions

diff --git a/dev-db/metakit/ChangeLog b/dev-db/metakit/ChangeLog
index ada3d91cc1c2..3df22ca858ba 100644
--- a/dev-db/metakit/ChangeLog
+++ b/dev-db/metakit/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-db/metakit
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-db/metakit/ChangeLog,v 1.62 2012/09/26 13:02:23 kensington Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-db/metakit/ChangeLog,v 1.63 2014/12/25 12:31:34 mgorny Exp $
+
+*metakit-2.4.9.7-r2 (25 Dec 2014)
+
+  25 Dec 2014; Michał Górny <mgorny@gentoo.org> +metakit-2.4.9.7-r2.ebuild:
+  Convert to python-single-r1.
 
   26 Sep 2012; Michael Palimaka <kensington@gentoo.org>
   -files/metakit-2.4.9.7-LDFLAGS.patch, -metakit-2.4.9.7.ebuild:
diff --git a/dev-db/metakit/metakit-2.4.9.7-r2.ebuild b/dev-db/metakit/metakit-2.4.9.7-r2.ebuild
new file mode 100644
index 000000000000..bf1f94a1fa93
--- /dev/null
+++ b/dev-db/metakit/metakit-2.4.9.7-r2.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-db/metakit/metakit-2.4.9.7-r2.ebuild,v 1.1 2014/12/25 12:31:34 mgorny Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit eutils flag-o-matic multilib python-single-r1 toolchain-funcs
+
+DESCRIPTION="Embedded database library"
+HOMEPAGE="http://www.equi4.com/metakit/"
+SRC_URI="http://www.equi4.com/pub/mk/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="python static tcl"
+
+DEPEND="python? ( ${PYTHON_DEPS} )
+	tcl? ( dev-lang/tcl )"
+RDEPEND="${DEPEND}"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RESTRICT="test"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	epatch "${FILESDIR}/${P}-linking.patch"
+}
+
+src_configure() {
+	local myconf mycxxflags
+	use tcl && myconf+=" --with-tcl=${EPREFIX}/usr/include,${EPREFIX}/usr/$(get_libdir)"
+	use static && myconf+=" --disable-shared"
+	use static || append-cxxflags -fPIC
+
+	CXXFLAGS="${CXXFLAGS} ${mycxxflags}" unix/configure \
+		${myconf} \
+		--host=${CHOST} \
+		--prefix="${EPREFIX}/usr" \
+		--libdir="${EPREFIX}/usr/$(get_libdir)" \
+		--infodir="${EPREFIX}/usr/share/info" \
+		--mandir="${EPREFIX}/usr/share/man"
+}
+
+src_compile() {
+	emake SHLIB_LD="$(tc-getCXX) -shared -Wl,-soname,libmk4.so.2.4"
+
+	if use python; then
+		emake \
+			SHLIB_LD="$(tc-getCXX) -shared" \
+			pyincludedir="$(python_get_includedir)" \
+			PYTHON_LIB="$(python_get_library)" \
+			python
+	fi
+}
+
+src_install () {
+	default
+
+	mv "${ED}"//usr/$(get_libdir)/libmk4.so{,.2.4}
+	dosym libmk4.so.2.4 /usr/$(get_libdir)/libmk4.so.2
+	dosym libmk4.so.2.4 /usr/$(get_libdir)/libmk4.so
+
+	if use python; then
+		mkdir -p "${D%/}$(python_get_sitedir)" || die
+		emake \
+			DESTDIR="${D}" \
+			pylibdir="$(python_get_sitedir)" \
+			install-python
+	fi
+
+	dohtml Metakit.html
+	dohtml -a html,gif,png,jpg -r doc/*
+}